forked from kara2810/NMPR---1.12
-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle
134 lines (109 loc) · 4.48 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
plugins {
id 'java-library'
id 'eclipse'
id 'idea'
id 'net.neoforged.gradle.userdev' version '7.0.107'
id 'net.darkhax.curseforgegradle' version '1.1.18'
id 'com.modrinth.minotaur' version "2.+"
}
version = "${version}"
group = "${mod_group}"
base {
archivesName = "${mod_archive_name}-${mc_version}"
}
// Mojang ships Java 17 to end users in 1.18+, so your mod should target Java 17.
java.toolchain.languageVersion = JavaLanguageVersion.of(17)
//minecraft.accessTransformers.file rootProject.file('src/main/resources/META-INF/accesstransformer.cfg')
//minecraft.accessTransformers.entry public net.minecraft.client.Minecraft textureManager # textureManager
runs {
// applies to all the run configs below
configureEach { net.neoforged.gradle.dsl.common.runs.run.Run run ->
// Recommended logging data for a userdev environment
systemProperty 'forge.logging.markers', 'REGISTRIES'
// Recommended logging level for the console
systemProperty 'forge.logging.console.level', 'debug'
//Limit ram usage for the dev environment to 4GB
jvmArgument '-Xmx4G'
if (run.project.javaToolchains.launcherFor(java.toolchain).map { it.metadata.vendor }.getOrElse("").contains("JetBrains")) {
run.jvmArgument("-XX:+AllowEnhancedClassRedefinition")
}
modSource project.sourceSets.main
}
client {
// Comma-separated list of namespaces to load gametests from. Empty = all namespaces.
systemProperty 'neoforge.enabledGameTestNamespaces', "${mod_id}"
}
server {
systemProperty 'neoforge.enabledGameTestNamespaces', "${mod_id}"
programArgument '--nogui'
}
data {
// example of overriding the workingDirectory set in configureEach above, uncomment if you want to use it
// workingDirectory project.file('run-data')
// Specify the modid for data generation, where to output the resulting resource, and where to look for existing resources.
programArguments.addAll '--mod', "${mod_id}", '--all', '--output', file('src/generated/resources/').getAbsolutePath(), '--existing', file('src/main/resources/').getAbsolutePath()
}
}
// Include resources generated by data generators.
sourceSets.main.resources { srcDir 'src/generated/resources' }
repositories {
maven {
url = "https://maven.blamejared.com"
}
}
dependencies {
implementation "net.neoforged:neoforge:${neo_version}"
compileOnly "mezz.jei:jei-${mc_version}-common-api:${jei_version}"
compileOnly "mezz.jei:jei-${mc_version}-neoforge-api:${jei_version}"
runtimeOnly "mezz.jei:jei-${mc_version}-neoforge:${jei_version}"
}
jar {
manifest {
attributes([
"Specification-Title" : "${mod_id}",
"Specification-Vendor" : "Mrbysco",
"Specification-Version" : "1", // We are version 1 of ourselves
"Implementation-Title" : project.name,
"Implementation-Version" : project.jar.archiveVersion,
"Implementation-Vendor" : "Mrbysco",
"Implementation-Timestamp": new Date().format("yyyy-MM-dd'T'HH:mm:ssZ")
])
}
}
if (System.getenv().CURSEFORGE_KEY) {
task curseforge(type: net.darkhax.curseforgegradle.TaskPublishCurseForge) {
apiToken = System.getenv().CURSEFORGE_KEY
def mainFile = upload(project.curseforge_id, jar)
mainFile.releaseType = 'beta'
mainFile.addGameVersion "NeoForge"
mainFile.addGameVersion "${mc_version}"
mainFile.addGameVersion "Java 17"
mainFile.changelog = file("$project.rootDir/changelog.md")
mainFile.changelogType = 'markdown'
// mainFile.addRequirement()
// mainFile.addOptional()
}
}
if (System.getenv().MODRINTH_KEY) {
modrinth {
token = System.getenv().MODRINTH_KEY
projectId = project.modrinth_id
versionType = "beta"
versionName = "${mod_name} ${mc_version}"
versionNumber = project.version
uploadFile = jar
changelog = file("$project.rootDir/changelog.md").text
gameVersions = ["${mc_version}"]
loaders = ["neoforge"]
}
}
tasks.withType(JavaCompile).configureEach {
options.encoding = 'UTF-8' // Use the UTF-8 charset for Java compilation
}
// IDEA no longer automatically downloads sources/javadoc jars for dependencies, so we need to explicitly enable the behavior.
idea {
module {
downloadSources = true
downloadJavadoc = true
}
}