-
Notifications
You must be signed in to change notification settings - Fork 0
/
stack.f90
497 lines (325 loc) · 11.6 KB
/
stack.f90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
module xxmodulebase___stack_ftl
!-------------------------------------------------------------------------------
! Copyright : 2022, Fran Martinez Fadrique <Fran.Martinez.Fadrique@gmail.com>
! Project : Atlantis
! Author : Fran Martinez Fadrique
! Language : Object Oriented Fortran 2018
! Reference : http://www.cplusplus.com/reference/queue/queue
! Synopsis : Stack (LIFO) container template
! Limitations with respect to STL C++
! - No emplace functions.
! - No swap functions.
!
! License : This file is part of the Fortran Template Library (FTL).
!
! FTL is free software: you can redistribute it and/or modify
! it under the terms of the GNU Lesser General Public License as
! published by the Free Software Foundation, either version 3 of
! the License, or (at your option) any later version.
!
! FTL is distributed in the hope that it will be useful,
! but WITHOUT ANY WARRANTY; without even the implied warranty of
! MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
! See the GNU Lesser General Public License for more details.
!
! You should have received a copy of the GNU Lesser General Public
! License along with FTL.
! If not, see <http://www.gnu.org/licenses/>.
!-------------------------------------------------------------------------------
!---USE statements--------------------------------------------------------------
use m_object
use xxuse__
!---End of use statements-------------------------------------------------------
implicit none
!---Public/Private declarations-------------------------------------------------
private
public xxtypebase___stack_ftl, xxconstructor___stack_ftl
!---End of public/private declarations------------------------------------------
!---Declaration of module variables---------------------------------------------
! Stack node type
type t_node
private
! The element data instance
class(xxtypebase__), pointer :: element => null()
! Pointer to the down node in the stack (null if bottom)
type(t_node), pointer :: pdown => null()
end type t_node
! Linked stack container type
type, extends(t_object) :: xxtypebase___stack_ftl
private
! The number of nodes in the stack
integer :: count = 0
! The top node
type(t_node), pointer :: ptop => null()
! The bottom node
type(t_node), pointer :: pbottom => null()
contains
! Insertion and removal
procedure :: push => stack_push
procedure :: pop => stack_pop
procedure :: clear => stack_clear
! Access
procedure :: top => stack_top
procedure :: bottom => stack_bottom
! Query
procedure :: size => stack_size
procedure :: empty => stack_empty
! Conversion
procedure :: array => stack_array
! Assignment
generic :: assignment(=) => stack_assign_from_stack, &
stack_assign_from_array
procedure :: stack_assign_from_stack
procedure, private :: stack_assign_from_array
! Destructor
final :: stack_
end type xxtypebase___stack_ftl
! Constructor interface
interface xxconstructor___stack_ftl
module procedure stack_default
module procedure stack_copy
module procedure stack_copy_from_array
end interface xxconstructor___stack_ftl
!---End of declaration of module variables--------------------------------------
contains
! Default constructor
function stack_default( ) result(res)
! The result stack
type(xxtypebase___stack_ftl) :: res
! Initialise
res%ptop => null()
res%pbottom => null()
res%count = 0
end function stack_default
! Copy constructor
function stack_copy( stack ) result(res)
! The input stack
type(xxtypebase___stack_ftl), intent(in) :: stack
! The result stack
type(xxtypebase___stack_ftl) :: res
! Copy the stack
res = stack
end function stack_copy
! Copy constructor from array
function stack_copy_from_array( a ) result(res)
! The input array
class(xxtypebase__), dimension(:), intent(in) :: a
! The result stack
type(xxtypebase___stack_ftl) :: res
! Copy the stack
res = a
end function stack_copy_from_array
! Destructor
subroutine stack_( this )
! The stack
type(xxtypebase___stack_ftl), intent(inout) :: this
! Clear the stack
if( this%count > 0 ) call this%clear()
end subroutine stack_
! Add a node to the top of the stack
subroutine stack_push( this, element )
! The stack
class(xxtypebase___stack_ftl), intent(inout) :: this
! The element
class(xxtypebase__), intent(in) :: element
! Local node pointer
type(t_node), pointer :: node
! Allocate the new node
allocate( node )
! Check if stack already contains elements
if( associated(this%ptop) ) then
! Reasign new node pointers
node%pdown => this%ptop
this%ptop => node
else
! Assign pointers
this%ptop => node
this%pbottom => this%ptop
end if
! Copy the element into its stack position
call element_assign_pointer( node%element, element )
! Increase counter
this%count = this%count + 1
end subroutine stack_push
! Remove node from the beginning of the stack
subroutine stack_pop( this )
! The stack
class(xxtypebase___stack_ftl), intent(inout) :: this
! Local node pointer
type(t_node), pointer :: node
! Check that the stack is not empty
if( associated(this%ptop) ) then
! Destroy data element in the top stack node
deallocate( this%ptop%element )
! Check if there is more than one node
if( associated(this%ptop%pdown) ) then
! More than one node in the stack; remove the top one
node => this%ptop
this%ptop => this%ptop%pdown
deallocate( node )
else
! Only one node in stack; remove it
deallocate( this%ptop )
this%pbottom => null()
end if
! Decrease counter
this%count = this%count - 1
end if
end subroutine stack_pop
! Return the element in the top (down to extract) node in the stack
pure function stack_top( this ) result(res)
! The stack
class(xxtypebase___stack_ftl), target, intent(in) :: this
! Pointer to the element in the top node in the stack
class(xxtypebase__), allocatable :: res
! Assign the return value
call element_assign_allocatable( res, this%ptop%element )
end function stack_top
! Return the element in the bottom (bottom to extract) node in the stack
pure function stack_bottom( this ) result(res)
! The stack
class(xxtypebase___stack_ftl), target, intent(in) :: this
! Pointer to the element in the bottom node in the stack
class(xxtypebase__), allocatable :: res
! Assign the return value
call element_assign_allocatable( res, this%pbottom%element )
end function stack_bottom
! Destroy a stack
subroutine stack_clear( this )
! The stack
class(xxtypebase___stack_ftl), intent(inout) :: this
! Local node pointers
type(t_node), pointer :: del, down
! Check if empty stack
if( associated( this%pbottom ) ) then
! Initialise stack navigation
del => this%ptop
! Navigate the stack
do while( associated(del) )
! Save pointer to down node
down => del%pdown
! Destroy data element in the current stack node
deallocate( del%element )
! Deallocate the stack node
deallocate( del )
! Irerate
del => down
end do
end if
! Reinitialise stack pointers
this%ptop => null()
this%pbottom => null()
! Reset counter
this%count = 0
end subroutine stack_clear
! Return total length of stack
pure function stack_size( this ) result(res)
! The stack
class(xxtypebase___stack_ftl), intent(in) :: this
! The stack size
integer :: res
! Assign the return value
res = this%count
end function stack_size
! Test whether stack is empty
pure function stack_empty( this ) result(res)
! The stack
class(xxtypebase___stack_ftl), intent(in) :: this
! The stack empty status
logical :: res
! Asign the return value
res = ( this%count == 0 )
end function stack_empty
! Create a stack from an exisiting stack (assignment operator)
subroutine stack_assign_from_stack( this, other )
! The output stack
class(xxtypebase___stack_ftl), intent(out) :: this
! The input stack
type(xxtypebase___stack_ftl), intent(in) :: other
! Local node pointers
type(t_node), pointer :: lptr, dptr
! Check if the input stack has elements
if( associated(other%ptop) ) then
! Initialise navigation pointer
lptr => other%pbottom
! Loop on the stack
do while( .not. associated(lptr,other%ptop) )
! Add element to the output stack
call this%push( lptr%element )
! Loop searching for the current pointer location
dptr => other%ptop
do while( .not. associated(dptr%pdown,lptr) )
dptr => dptr%pdown
end do
! Iterate
lptr => dptr
end do
! Add the top element
call this%push(other%ptop%element)
end if
end subroutine stack_assign_from_stack
! Create a stack from an array (assignment operator)
subroutine stack_assign_from_array( this, array )
! The output stack
class(xxtypebase___stack_ftl), intent(out) :: this
! The input array
class(xxtypebase__), dimension(:), intent(in) :: array
! Local counter
integer :: i
! Loop on the input array
do i = 1, size(array)
! Add element to the output stack
call this%push( array(i) )
end do
end subroutine stack_assign_from_array
! Create an array (allocatable) of elements from a stack (bottom to top)
function stack_array( this ) result(res)
! The input stack
class(xxtypebase___stack_ftl), intent(in) :: this
! The returned array of elements (unallocated if memory failure)
class(xxtypebase__), allocatable, dimension(:) :: res
! Local node pointers
type(t_node), pointer :: lptr
! Local counter
integer :: i
! Memory allocation status
integer :: status
! Allocate memory for returned array
allocate( res( this%size() ), stat=status )
if( status == 0 ) then
! Initialise navigation pointer
lptr => this%ptop
! Loop on the elements
do i = this%size(), 1, -1
res(i) = lptr%element
lptr => lptr%pdown
end do
end if
end function stack_array
! Implement the assignment between two elements (contained in the container node)
! Centralises the implementation allowing the handling of polymorphism (store parent classes pointing derived clasess)
! at the time thta allows the invocation of assignment operators in the cases when the element implements it
pure subroutine element_assign_pointer( left, right )
! Element to be allocated and assigned (pointer interface)
class(xxtypebase__), pointer, intent(inout) :: left
! Source element
class(xxtypebase__), intent(in) :: right
! Allocate first. Use mold to allow polymorphic object storage through parent class
allocate( left, mold=right )
! Assign explicitly to allow invoking the assignment operator if implemented in the element
left = right
end subroutine element_assign_pointer
! Implement the assignment between two elements (contained in the container node)
! Centralises the implementation allowing the handling of polymorphism (store parent classes pointing derived clasess)
! at the time thta allows the invocation of assignment operators in the cases when the element implements it
pure subroutine element_assign_allocatable( left, right )
! Element to be allocated and assigned (allocatable interface)
class(xxtypebase__), allocatable, intent(inout) :: left
! Source element
class(xxtypebase__), intent(in) :: right
! Allocate first. Use mold to allow polymorphic object storage through parent class
allocate( left, mold=right )
! Assign explicitly to allow invoking the assignment operator if implemented in the element
left = right
end subroutine element_assign_allocatable
end module xxmodulebase___stack_ftl