-
Notifications
You must be signed in to change notification settings - Fork 4
/
flake.nix
53 lines (49 loc) · 1.84 KB
/
flake.nix
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
{
description = "A very opinionated Matrix TUI";
inputs = {
nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
rust-overlay.url = "github:oxalica/rust-overlay";
flake-utils.url = "github:numtide/flake-utils";
};
outputs = { nixpkgs, rust-overlay, flake-utils, ... }:
flake-utils.lib.eachDefaultSystem (system:
let
overlays = [ (import rust-overlay) ];
pkgs = import nixpkgs { inherit system overlays; };
rusttoolchain =
pkgs.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;
cargoToml = (builtins.fromTOML (builtins.readFile ./Cargo.toml));
sharedDeps = with pkgs; [ rusttoolchain pkg-config ]
++ pkgs.lib.optionals pkgs.stdenv.isDarwin
[ pkgs.darwin.apple_sdk.frameworks.Security ];
in
rec {
# `nix build`
packages = {
matui = pkgs.rustPlatform.buildRustPackage {
pname = cargoToml.package.name;
version = cargoToml.package.version;
src = ./.;
cargoLock = {
outputHashes = {
"matrix-sdk-0.6.2" = "sha256-uV+pKHrAvApNrynyzQgxDCPZ3RKMO2FviBL4n+RDPzc=";
"ruma-0.8.2" = "sha256-tgqUqiN6LNUyz5I6797J0YFsiFyYWfexa7n2jwUoHWA=";
"vodozemac-0.3.0" = "sha256-tAimsVD8SZmlVybb7HvRffwlNsfb7gLWGCplmwbLIVE=";
};
lockFile = ./Cargo.lock;
};
# won't be found by `openssl-sys` if it's in `nativeBuildInputs`
buildInputs = with pkgs;
[ openssl ];
nativeBuildInputs = with pkgs;
sharedDeps ++ [ ffmpeg ];
};
default = packages.matui;
};
# `nix develop`
devShells.default = pkgs.mkShell {
buildInputs = with pkgs;
sharedDeps ++ [ bacon openssl ];
};
});
}