-
Notifications
You must be signed in to change notification settings - Fork 0
/
il_qtom.inc
238 lines (223 loc) · 5.84 KB
/
il_qtom.inc
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
; Inline; isn't a called function
QuattoRotM:
ld ix,QC
ld iy,RotM
ld a,(ix+Q_D)
ld l,(ix+Q_D+1)
ld h,(ix+Q_D+2) ; AHL = QR.z
call fSquare ; z^2
push af \ push hl \ push de ; push AHLDE, {z^2}
exx \ ex af,af' ; acc' = z^2
ld a,(ix+Q_C)
ld l,(ix+Q_C+1)
ld h,(ix+Q_C+2) ; AHL = QR.y
call fSquare ; y^2
push af \ push hl \ push de ; push AHLDE, {z^2, y^2}
call fAddAcc
push af \ push hl \ push de ; push AHLDE, {z^2, y^2, z^2+y^2}
exx \ ex af,af' ; acc' = z^2 + y^2
ld a,(ix+Q_B)
ld l,(ix+Q_B+1)
ld h,(ix+Q_B+2) ; AHL = QR.x
call fSquare ; x^2
push af \ push hl \ push de ; push AHLDE {z^2, y^2, z^2+y^2, x^2}
call fAddAcc
exx \ ex af,af' ; acc' = z^2 + y^2 + x^2
ld a,(ix+Q_A)
ld l,(ix+Q_A+1)
ld h,(ix+Q_A+2) ; AHL = QR.r
call fSquare ; r^2
call fAddAcc ; AHLDE = z^2 + y^2 + x^2 + r^2
ld b,a
and $7F ; == 0 or == -0
ld a,b
jp z,RotMIdentity ; AHLDE == 0
call fTrunc
ex de,hl \ ld c,a ; CDE = AHL
ld a,$40 \ ld hl,$8000 ; AHL = 2.0
call fDiv ; S = 2/CDE
ld (QtR_S),a \ ld (QtR_S+1),hl ; S = AHL
ld ix,QC ; clobbered by fDiv
ld a,(ix+Q_C)
ld l,(ix+Q_C+1)
ld h,(ix+Q_C+2)
ex de,hl \ ld c,a ; CDE = QR.y
ld a,(ix+Q_B)
ld l,(ix+Q_B+1)
ld h,(ix+Q_B+2) ; AHL = QR.x
call fMult ; B = y*x
push af \ push hl \ push de ; push B, {z^2, y^2, z^2+y^2, x^2, B}
exx \ ex af,af' ; acc' = B
ld a,(ix+Q_A)
ld l,(ix+Q_A+1)
ld h,(ix+Q_A+2)
ex de,hl \ ld c,a ; CDE = QR.r
ld a,(ix+Q_D)
ld l,(ix+Q_D+1)
ld h,(ix+Q_D+2) ; AHL = QR.z
call fMult ; I = r*z
push af \ push hl \ push de ; push I, {z^2, y^2, z^2+y^2, x^2, B, I}
xor $80 ; I = -I
call fAddAcc ; B-I
call fTrunc
ex de,hl \ ld c,a ; CDE = (B-I)
ld a,(QtR_S) \ ld hl,(QtR_S+1) ; AHL = S
call fMult ; (B-I)*S
call fTrunc
ld (iy+RotM01+0),a
ld (iy+RotM01+1),l
ld (iy+RotM01+2),h ; M01 = (B-I)*S
pop de \ pop hl \ pop af ; I
exx \ ex af,af' ; acc' = I
pop de \ pop hl \ pop af ; B
call fAddAcc ; I+B
call fTrunc
ex de,hl \ ld c,a ; CDE = (I+B)
ld a,(QtR_S) \ ld hl,(QtR_S+1) ; AHL = S
call fMult ; (B+I)*S
call fTrunc
ld (iy+RotM10+0),a
ld (iy+RotM10+1),l
ld (iy+RotM10+2),h ; M10 = (B+I)*S
ld a,(ix+Q_D)
ld l,(ix+Q_D+1)
ld h,(ix+Q_D+2)
ex de,hl \ ld c,a ; CDE = QR.z
ld a,(ix+Q_B)
ld l,(ix+Q_B+1)
ld h,(ix+Q_B+2) ; AHL = QR.x
call fMult ; C = z*x
push af \ push hl \ push de ; push C, {z^2, y^2, z^2+y^2, x^2, C}
exx \ ex af,af' ; acc' = C
ld a,(ix+Q_A)
ld l,(ix+Q_A+1)
ld h,(ix+Q_A+2)
ex de,hl \ ld c,a ; CDE = QR.r
ld a,(ix+Q_C)
ld l,(ix+Q_C+1)
ld h,(ix+Q_C+2) ; AHL = QR.y
call fMult ; G = r*y
push af \ push hl \ push de ; push I, {z^2, y^2, z^2+y^2, x^2, C, G}
call fAddAcc ; C+G
call fTrunc
ex de,hl \ ld c,a ; CDE = (C+G)
ld a,(QtR_S) \ ld hl,(QtR_S+1) ; AHL = S
call fMult ; (C+G)*S
call fTrunc
ld (iy+RotM02+0),a
ld (iy+RotM02+1),l
ld (iy+RotM02+2),h ; M02 = (C+G)*S
pop de \ pop hl \ pop af ; G
xor $80 ; G = -G
exx \ ex af,af' ; acc' = G
pop de \ pop hl \ pop af ; C
call fAddAcc ; C-G
call fTrunc
ex de,hl \ ld c,a ; CDE = (C-G)
ld a,(QtR_S) \ ld hl,(QtR_S+1) ; AHL = S
call fMult ; (C-G)*S
call fTrunc
ld (iy+RotM20+0),a
ld (iy+RotM20+1),l
ld (iy+RotM20+2),h ; M20 = (C-G)*S
ld a,(ix+Q_D)
ld l,(ix+Q_D+1)
ld h,(ix+Q_D+2)
ex de,hl \ ld c,a ; CDE = QR.z
ld a,(ix+Q_C)
ld l,(ix+Q_C+1)
ld h,(ix+Q_C+2) ; AHL = QR.y
call fMult ; F = z*y
push af \ push hl \ push de ; push F, {z^2, y^2, z^2+y^2, x^2, F}
exx \ ex af,af' ; acc' = F
ld a,(ix+Q_A)
ld l,(ix+Q_A+1)
ld h,(ix+Q_A+2)
ex de,hl \ ld c,a ; CDE = QR.r
ld a,(ix+Q_B)
ld l,(ix+Q_B+1)
ld h,(ix+Q_B+2) ; AHL = QR.x
call fMult ; D = r*x
push af \ push hl \ push de ; push D, {z^2, y^2, z^2+y^2, x^2, F, D}
xor $80 ; D = -D
call fAddAcc ; F-D
call fTrunc
ex de,hl \ ld c,a ; CDE = (F-D)
ld a,(QtR_S) \ ld hl,(QtR_S+1) ; AHL = S
call fMult ; (F-D)*S
call fTrunc
ld (iy+RotM12+0),a
ld (iy+RotM12+1),l
ld (iy+RotM12+2),h ; M12 = (F-D)*S
pop de \ pop hl \ pop af ; D
exx \ ex af,af' ; acc' = D
pop de \ pop hl \ pop af ; F
call fAddAcc ; F+D
call fTrunc
ex de,hl \ ld c,a ; CDE = (F+D)
ld a,(QtR_S) \ ld hl,(QtR_S+1) ; AHL = S
call fMult ; (F+D)*S
call fTrunc
ld (iy+RotM21+0),a
ld (iy+RotM21+1),l
ld (iy+RotM21+2),h ; M20 = (F+D)*S
pop de \ pop hl \ pop af ; x^2, {z^2, y^2, z^2+y^2}
exx \ ex af,af' ; acc' = x^2
pop de \ pop hl \ pop af ; AHLDE = z^2+y^2, {z^2, y^2}
call fTrunc
ex de,hl \ ld c,a ; CDE = z^2+y^2
ld a,(QtR_S) \ ld hl,(QtR_S+1) ; AHL = S
call fMult ; (zz+yy)*S
xor $80 ; -(zz+yy)*S
exx \ ex af,af' ; acc' = -(zz+yy)*S, AHLDE = x^2
push af \ push hl \ push de ; x^2, {z^2, y^2, x^2}
ld a,$3F \ ld hl,$8000 \ ld d,l \ ld e,l ; AHLDE = 1.0
call fAddAcc ; 1 - (zz+yy)*S
call fTrunc
ld (iy+RotM00+0),a
ld (iy+RotM00+1),l
ld (iy+RotM00+2),h ; M00 = 1 - (zz+yy)*S
pop de \ pop hl \ pop af ; x^2, {z^2, y^2}
exx \ ex af,af' ; acc' = x^2
pop de \ pop hl \ pop af ; y^2, {z^2}
exx \ ex af,af' ; acc' = y^2, ahlde = x^2
push af \ push hl \ push de ; x^2, {z^2, x^2}
call fAddAcc ; x^2+y^2
call fTrunc
ex de,hl \ ld c,a ; CDE = x^2+y^2
ld a,(QtR_S) \ ld hl,(QtR_S+1) ; AHL = S
call fMult ; (xx+yy)*S
xor $80 ; -(xx+yy)*S
exx \ ex af,af' ; acc' = -(xx+yy)*S
ld a,$3F \ ld hl,$8000 \ ld d,l \ ld e,l ; AHLDE = 1.0
call fAddAcc ; 1 - (xx+yy)*S
call fTrunc
ld (iy+RotM22+0),a
ld (iy+RotM22+1),l
ld (iy+RotM22+2),h ; M22 = 1 - (xx+yy)*S
pop de \ pop hl \ pop af ; x^2, {z^2}
exx \ ex af,af' ; acc' = x^2
pop de \ pop hl \ pop af ; z^2, {}
call fAddAcc ; x^2+z^2
call fTrunc
ex de,hl \ ld c,a ; CDE = x^2+z^2
ld a,(QtR_S) \ ld hl,(QtR_S+1) ; AHL = S
call fMult ; (xx+zz)*S
xor $80 ; -(xx+zz)*S
exx \ ex af,af' ; acc' = -(xx+zz)*S
ld a,$3F \ ld hl,$8000 \ ld d,l \ ld e,l ; AHLDE = 1.0
call fAddAcc ; 1 - (xx+zz)*S
call fTrunc
ld (iy+RotM11+0),a
ld (iy+RotM11+1),l
ld (iy+RotM11+2),h ; M11 = 1 - (xx+zz)*S
; ret
jr QuattoRotMExit
RotMIdentity:
ld hl,3*4*2 ; un-push 12 times
add hl,sp
ld sp,hl
ld hl,RotM
call MLoadIdentity
QuattoRotMExit:
; End Quat to RotM