-
Notifications
You must be signed in to change notification settings - Fork 0
/
moniteur.asm
1079 lines (889 loc) · 36.1 KB
/
moniteur.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
;*******************************************************************************
;* Language : Motorola/Freescale/NXP 68HC11 Assembly Language (aspisys.com/ASM11)
;*******************************************************************************
;* 68HC11 Monitor V1.3 CRC: $8E5B
;*
;* By : Sylvain Bissonnette
;* 8382 De Fougeray
;* Anjou, Que.
;* H1K 1K6
;*******************************************************************************
;* 98.09.15 Adapted to ASM11 and English by Tony G. Papadimitriou <tonyp@acm.org>
;* Shortened messages to fit even in M68HC811E2 and optimized code in
;* several places. INCAR changed to return UPPER always. Also, fixed
;* a couple or so bugs.
;* 02.04.30 Further optimizations and minor corrections.
;*******************************************************************************
#ifdef ?
#Hint +---------------------------------------------------
#Hint | Available conditionals (for use with -Dx option)
#Hint +---------------------------------------------------
#Hint | DEBUG: for SIM11x runs (faster bps, etc.)
#Hint | GREEK: for Greek language messages
#Hint | E2...: Target is 811E2 MCU (default)
#Hint | F1...: Target is ASPiSYS F1 Board (32K+32K memory)
#Hint | WSI..: Target is WSI DK68HC11 Development Kit
#Hint | MHZ:<value>: 8 or 16 for corresponding crystal
#Hint +---------------------------------------------------
#Fatal Run ASM11 -Dx (where x is any of the above)
#endif
#ListOff
#Uses mcu.inc ;found in ASM11 distribution
#ListOn
PROMPTCH def '>'
#ifdef DEBUG
#Hint Assembling in DEBUG mode (do NOT burn device)
BaudRate def $00 ;max bps for SIM11E
#endif
#if MHZ = 8
BaudRate def $30 ;9600 bps for normal run
#else if MHZ = 16
BaudRate def $31 ;9600 bps for normal run
#else ifdef __WSI__
BaudRate def $04 ;9600 bps for normal run
#endif
;*******************************************************************************
#RAM
;*******************************************************************************
; Usage registers
REGCCR rmb 1
REGB rmb 1
REGA rmb 1
REGX rmb 2
REGY rmb 2
REGPC rmb 2
REGST rmb 2
; Buffer getkey
QIN rmb 2
BUFFER rmb 4
PRESCALE rmb 1 ;PRESCALER VALUE
RESTART rmb 1 ;RESTART VALUE
STARTUP rmb 1 ;RESET VARIABLE
org $C1 ; Pseudo-vector registers
PSSCI rmb 3
PSSPI rmb 3
PSPAI rmb 3
PSPAO rmb 3
PSTO rmb 3
PSTOC5 rmb 3
PSTOC4 rmb 3
PSTOC3 rmb 3
PSTOC2 rmb 3
PSTOC1 rmb 3
PSTIC3 rmb 3
PSTIC2 rmb 3
PSTIC1 rmb 3
PSRTI rmb 3
PSIRQ rmb 3
PSXIRQ rmb 3
PSSWI rmb 3
PSIOT rmb 3
PSCOPF rmb 3
PSCOPC rmb 3
PSRESET rmb 3
;*******************************************************************************
#ROM
;*******************************************************************************
Start proc
lda #$08 ; RESET ON STOP CLOCK
sta OPTION
lda #$AA
cmpa STARTUP
bne Go@@
sta STARTUP
lda PRESCALE ; SET THE PRESCALER FOR 64xE
anda #%11
sta TMSK2
Go@@ sei ; Mask IRQ & FIRQ
@SetChipSelects
#ifdef __WSI__
bsr SetupWSI
#endif
cls ; Allow STOPs
clr RESTART ; Met RESTART a $00 quand power on
bsr INIVEC ; Initialization of the pseudo-vectors
bsr INISCI ; Initialization of the ACIA for communication
jsr SNDCRLF
bsr MENU ; Display the menu
MainLoop bsr WAITCOM ; Wait for a command
bra MainLoop
;*******************************************************************************
;* Wait for a command from the terminal and execute it
;*******************************************************************************
WAITCOM proc
jsr PROMPT
jsr INCAR
cmpa #'S' ; Download S19
jeq S1S9
cmpa #'G' ; Execute program in RAM
jeq EXEC
cmpa #'R' ; Reset system
beq Start
cmpa #'M' ; Display Command Menu
beq Menu@@
cmpa #'C' ; Continue after an SWI
beq Continue@@
cmpa #'E' ; Examine memory
jeq MEMEX
cmpa #'P' ; Adjust the prescaler
jeq PSCALE
rts
Menu@@ clr RESTART
bra MENU
Continue@@ jsr SNDCRLF
ldx #GOMSG1
jmp SNDMSG_CRLF
;*******************************************************************************
;* Menu
;*******************************************************************************
MENU proc
ldx #MENUMSG ; Display the copyright
jsr SNDMSG
lda #$AA
cmpa RESTART
beq Done@@
sta RESTART
ldx #MENUMSG2
jmp SNDMSG_CRLF ; Display the command menu
Done@@ equ :AnRTS
;*******************************************************************************
;* Initialization of the ACIA for communication 9600 bps, 8 bit, no parity, 1 sb
;*
;* Reg aff: A,CCR
;*******************************************************************************
INISCI proc
lda #BaudRate
sta BAUD
clr SCCR1 ; 8 BIT, NO WAKE UP, 1 STOP BIT
lda #%1100 ; NO INTERRUPT, TX ENABLE, RX ENABLE
sta SCCR2
rts
;*******************************************************************************
;* Initialization of the pseudo-vectors
;*******************************************************************************
INIVEC proc
ldx #VECTAB
ldy #PSSCI
Loop@@ cmpx #VECTAB_END
beq Done@@
lda ,x
sta ,y
inx
iny
bra Loop@@
Done@@ equ :AnRTS
;*******************************************************************************
;* SWI Interrupt Handler
;*******************************************************************************
SWI_Handler proc
bsr Copy
Loop@@ jsr SNDCRLF
ldx #SWIMSG
jsr SNDMSG
jsr INCAR
cmpa #'C'
bne Loop@@
rti
;*******************************************************************************
; Used by SWI_Handler (above) and IOT_Handler (below)
Copy proc
tsx
dex:2 ;cancel out the return address
ldy #REGCCR
Loop@@ lda ,x
sta ,y
inx
iny
cmpy #REGST
bne Loop@@
stx REGST
bra SWIRES
;*******************************************************************************
;* IOT Interrupt Handler
;*******************************************************************************
IOT_Handler proc
bsr Copy
tsx ; Adjust the return address
ldd PC_,x ;BUG FIXED. Was: LDB #8
incd ; ABX
std PC_,x ; INC ,x (increments only lower PC)
rti
;*******************************************************************************
SWIRES proc
jsr SNDCRLF ; Advance line
ldx #SWMSG1
jsr SNDMSG_CRLF
ldx #SWMSG2 ; REG A
jsr SNDMSG
lda REGA
jsr OUT2HA
ldx #SWMSG3 ; REG B
jsr SNDMSG
lda REGB
jsr OUT2HA
ldx #SWMSG4 ; REG X
jsr SNDMSG
ldx REGX
jsr OUT4HX
ldx #SWMSG5 ; REG Y
jsr SNDMSG
ldx REGY
jsr OUT4HX
ldx #SWMSG6 ; REG S
jsr SNDMSG
ldx REGST
jsr OUT4HX
ldx #SWMSG7 ; REG PC
jsr SNDMSG
ldx REGPC
jsr OUT4HX
jsr SNDCRLF_TWICE
ldx #SWMSG8 ; REG CC
jsr SNDMSG_CRLF
ldx #SWMSG9
jsr SNDMSG
ldb REGCCR
clrx
Loop@@ clra
lslb
adca #'0'
jsr PutChar
lda #' '
jsr PutChar
inx
cmpx #8
bne Loop@@
jsr SNDCRLF_TWICE
ldx #SWMSG10
jsr SNDMSG
tsx ;Display the Stack Pointer
ldb #8 ;not counting the stacked frame
abx
jsr OUT4HX
jmp SNDCRLF
;*******************************************************************************
;* Interrupt Messages
;*******************************************************************************
SCI proc
ldx #SCIMSG
bra MESSINT
SPI proc
ldx #SPIMSG
bra MESSINT
PAI proc
ldx #PAIMSG
bra MESSINT
PAO proc
ldx #PAOMSG
bra MESSINT
TOV proc
ldx #TOVMSG
bra MESSINT
TOC5! proc
ldx #TOC5MSG
bra MESSINT
TOC4! proc
ldx #TOC4MSG
bra MESSINT
TOC3! proc
ldx #TOC3MSG
bra MESSINT
TOC2! proc
ldx #TOC2MSG
bra MESSINT
TOC1! proc
ldx #TOC1MSG
bra MESSINT
TIC3! proc
ldx #TIC3MSG
bra MESSINT
TIC2! proc
ldx #TIC2MSG
bra MESSINT
TIC1! proc
ldx #TIC1MSG
bra MESSINT
RTI_INT proc
ldx #RTIMSG
bra MESSINT
IRQ proc
ldx #IRQMSG
bra MESSINT
XIRQ proc
ldx #XIRQMSG
bra MESSINT
SWII proc
ldx #SWIIMSG
bra MESSINT2
IOTT proc
ldx #IOTTMSG
bra MESSINT3
COPF proc
ldx #COPFMSG
bra MESSINT4
COPC proc
ldx #COPCMSG
bra MESSINT4
RES proc
ldx #RESMSG
MESSINT bsr CRMSGCR
rti
;-------------------------------------------------------------------------------
CRMSGCR jsr SNDCRLF
jmp SNDMSG_CRLF
MESSINT2 bsr CRMSGCR
jmp SWI_Handler
MESSINT3 bsr CRMSGCR
jmp IOT_Handler
MESSINT4 bsr CRMSGCR
jmp Start
;*******************************************************************************
;* Examine memory
;*******************************************************************************
MEMEX proc
jsr SNDCRLF
ldx #EXMSG1
jsr SNDMSG
jsr GET4HX
Loop@@ jsr SNDCRLF
jsr OUT4HX
lda #':'
bsr PutChar
lda ,x
bsr OUT2HA
GetChar@@ jsr INCAR
cmpa #'+'
beq Plus@@
cmpa #'-'
beq Minus@@
cmpa #'/'
beq Divide@@
cmpa #CR
bne GetChar@@
jsr INCAR
jmp MENU
Plus@@ inx
bra Loop@@
Minus@@ dex
bra Loop@@
Divide@@ lda #' '
bsr PutChar
lda #'/'
bsr PutChar
jsr GET2HA
sta ,x
bra Loop@@
;*******************************************************************************
;* Adjust the prescaler
;*******************************************************************************
PSCALE proc
ldx #PSCALEM
bsr SNDCRLF
bsr SNDMSG
jsr GET1HA
sta PRESCALE
cls
Halt@@ sei
stop
bra Halt@@ ;Needed to avoid run-away
;*******************************************************************************
PROMPT proc
lda #CR
bsr PutChar
lda #PROMPTCH ; Display Prompt Character
; bra PutChar
;*******************************************************************************
;* Send RegA to the serial port
;*
;* Reg aff:CCR
;*******************************************************************************
PutChar proc
cmpa #LF
bne PutChar@@
lda #CR
bsr PutChar@@
lda #LF
PutChar@@ tst SCSR
bpl PutChar@@
sta SCDR
rts
;*******************************************************************************
;* Routine to transmit the number in RegA to the terminal in ASCII format.
;*
;* Reg aff:CCR
;*******************************************************************************
OUT2HA proc
psha:2
lsra:4
jsr HEXASC ;convert
bsr PutChar ;transmit the MSB
pula
anda #$0F
jsr HEXASC ;convert
bsr PutChar ;transmit the LSB
pula
rts
;*******************************************************************************
;* Routine to transmit the number in RegB to the terminal in ASCII format.
;*
;* Reg aff:CCR
;*******************************************************************************
OUT2HB proc
psha
tba
bsr OUT2HA
pula
rts
;*******************************************************************************
;* Routine to transmit the number in RegX to the terminal in ASCII format.
;*
;* Reg aff:CCR
;*******************************************************************************
OUT4HX proc
pshd
pshx
xgdx
bsr OUT2HA
tba
bsr OUT2HA
pulx
puld
rts
;*******************************************************************************
;* Transmit a Carriage Return
;*
;* Reg aff: CCR
;*******************************************************************************
SNDCRLF_TWICE proc
bsr SNDCRLF
; bra SNDCRLF
;*******************************************************************************
SNDCRLF proc
psha
lda #LF
bsr PutChar
pula
rts
;*******************************************************************************
;* Send a string through the serial port
;*
;* X= String address
;*
;* Reg aff:A,x,CC
;*******************************************************************************
SNDMSG proc
Loop@@ lda ,x
beq Done@@
inx
bsr PutChar
bra Loop@@
Done@@ equ :AnRTS
;*******************************************************************************
SNDMSG_CRLF proc
bsr SNDMSG
bra SNDCRLF
;*******************************************************************************
;* LOOKCAR - Probe serial port, and load character if there is one
;*
;* C=1, no character
;* C=0, character in RegA
;*
;* Reg Aff: A,CCR
;*******************************************************************************
LOOKCAR proc
lda SCSR
bita #$20
beq Fail@@ ;If no char waiting, get out
lda SCDR
clc ;Character received
rts
Fail@@ sec
rts
;*******************************************************************************
;* INCAR - Check serial port and return character if one found
;*
;* Reg Aff: A,CCR
;*******************************************************************************
INCAR proc
bsr LOOKCAR
bcs INCAR
; bra UPPER
;*******************************************************************************
;* Convert to uppercase
;*******************************************************************************
UPPER proc
cmpa #'a'
blo Done@@
cmpa #'z'
bhi Done@@
suba #'a'-'A'
Done@@ rts
;*******************************************************************************
;* Routine pour lire un chiffre
;* hexa --> LSB de acc.A
;*
;* Reg aff:A,CCR
;*******************************************************************************
IN1HA proc
bsr INCAR
jmp ASCHEX
;*******************************************************************************
;* Routine pour lire un nombre
;* hexa --> acc.A
;*
;* Reg aff:A,CCR
;*******************************************************************************
IN2HA proc
pshx
bsr IN1HA
asla:4
psha
bsr IN1HA
tsx
ora ,x
ins
pulx
rts
;*******************************************************************************
;* Routine qui attend du terminal une nombre hexa. de 16 bits (4 touches)
;* Le nombre est plac dans le reg.X
;*
;* Reg aff:X,CCR
;*******************************************************************************
IN4HX proc
pshd
bsr IN2HA
psha
bsr IN2HA
tab
pula
xgdx
puld
rts
;*******************************************************************************
;* Routine pour lire un chiffre hexadecimal provenant du terminal.
;* par.d'entree: acc.A = qte de car.
;* a recevoir.
;* maximum = 4
;* par.de sortie:BUFFER contient
;* les car. recus
;*******************************************************************************
GETHEX proc
pshx
pshb
ldx #BUFFER
tab
abx
stx QIN
ldx #BUFFER ;adr. du dernier car a recevoir.
Loop@@ bsr INCAR
cmpa #BS ;BACKSPACE ?
bne CR@@
cpx #BUFFER
beq Loop@@
dex
jsr PutChar ;echo the backspace
bra Loop@@
CR@@ cmpa #CR ;RETURN ?
bne Decode@@
cpx QIN ;test si recu tous les car.
bne Loop@@ ;non, attend les autres car.
pulb
pulx
rts
Decode@@ cmpa #'0' ;decode si le car. est hexa.
blo Loop@@
cmpa #'F'
bhi Loop@@
cmpa #'9'
bls Q@@
cmpa #'A'
blo Loop@@ ;not hex, restart
Q@@ cmpx QIN ;si tous les car. sont recus,
beq Loop@@ ;attend la touche RETURN
jsr PutChar ;echo char
suba #'0' ;convert ASCII-->hex
cmpa #9
bls Save@@
suba #'A'-'0'-10 ;adjust for codes A-F
Save@@ sta ,x ;save the digit in the buffer
inx
bra Loop@@ ;attend prochain car.
;*******************************************************************************
;* Routine pour lire un chiffre
;* hexa --> LSB de acc. A
;*
;* Reg Aff: A,CCR
;*******************************************************************************
GET1HA proc
lda #1
bsr GETHEX
lda BUFFER
rts
;*******************************************************************************
;* Assemble 2 chiffre hexa dans le buffer et les places dans A
;*******************************************************************************
ASS2HEX proc
lda ,x
asla:4
psha
lda 1,x
inx:2
pshx
tsx
ora 2,x
pulx
ins
rts
;*******************************************************************************
;* Routine pour lire un nombre hexa
;* --> acc. A
;*
;* Reg Aff: A,CCR
;*******************************************************************************
GET2HA proc
pshx
lda #2
bsr GETHEX
ldx #BUFFER
bsr ASS2HEX
pulx
rts
;*******************************************************************************
;* Routine qui attend du terminal un nombre hexa de 16 bits (4 touches)
;* le nombre est placer dans le reg. X
;*
;* Reg Aff: X,CCR
;*******************************************************************************
GET4HX proc
pshd
clra
bsr GETHEX
ldx #BUFFER
bsr ASS2HEX
psha
bsr ASS2HEX
tab
pula
xgdx
puld
rts
;*******************************************************************************
;* Convertion de ASCII->HEXA
;*******************************************************************************
ASCHEX proc
suba #'0'
cmpa #9
bls Done@@
suba #'A'-'0'-10
Done@@ rts
;*******************************************************************************
;* Conversion routine HEXA-->ASCII
;*******************************************************************************
HEXASC proc
adda #'0'
cmpa #'9'
bls Done@@
adda #'A'-'0'-10
Done@@ rts
;*******************************************************************************
;* Transfer a S19 file
;*******************************************************************************
S1S9 proc
jsr INCAR
cmpa #'0'
beq S1@@
cmpa #'1'
beq S1@@
cmpa #'9'
beq S9@@
rts
S1@@ jsr IN2HA
tab
subb #3
jsr IN4HX
Loop@@ jsr IN2HA
sta ,x
inx
decb
bne Loop@@
jmp IN2HA
S9@@ jsr IN4HX
jmp IN4HX
;*******************************************************************************
;* Execute a program in RAM
;*******************************************************************************
EXEC proc
jsr SNDCRLF
ldx #EXECMSG
jsr SNDMSG
bsr GET4HX
ldy #Start
pshy
pshx
rts
MENUMSG fcb ASCII_FF
fcc 'ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»',LF
#ifdef F1
fcc 'º 68HC11 F1 MONITOR 1.3a º',LF
#else
fcc 'º 68HC11 EVBU MONITOR 1.3aº',LF
#endif
#ifdef GREEK
#Message Greek Language
fcc 'º Áðü: ÓõëâÝí ÌðéóóïííÝôô º',LF
fcc 'º Mod: Ôþíç Ðáðáäçìçôñßïõ º',LF
fcs 'ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍͼ',LF,LF
#else
#Message English Language
fcc 'º By: Sylvain Bissonnette º',LF
fcc 'º Mod: Tony Papadimitriou º',LF
fcs 'ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍͼ',LF,LF
#endif
#ifdef GREEK
MENUMSG2 fcc 'G: ÅêôÝëåóç êþäéêá óôçí RAM',LF
fcc 'R: Åðáíåêêßíçóç óõóôÞìáôïò',LF
fcc 'M: Ðáñïõóßáóç Ìåíïý',LF
fcc 'C: ÓõíÝ÷éóç ìåôÜ áðü SWI',LF
fcc 'E: Åëåã÷ïò ìíÞìçò',LF
fcc 'P: Ñýèìéóç prescaler',LF
fcs 'S19 ìåôáöïñÜ áðåõèåßáò',LF
#else
MENUMSG2 fcc 'G: Run code in RAM',LF
fcc 'R: Reset system',LF
fcc 'M: Display Menu',LF
fcc 'C: Continue after SWI',LF
fcc 'E: Examine memory',LF
fcc 'P: Adjust prescaler',LF
fcs 'S19 upload directly',LF
#endif
VECTAB jmp SCI
jmp SPI
jmp PAI
jmp PAO
jmp TOV
jmp TOC5!
jmp TOC4!
jmp TOC3!
jmp TOC2!
jmp TOC1!
jmp TIC3!
jmp TIC2!
jmp TIC1!
jmp RTI_INT
jmp IRQ
jmp XIRQ
jmp SWII
jmp IOTT
jmp COPF
jmp COPC
jmp Start
VECTAB_END
#ifdef GREEK
EXECMSG fcs 'ÅêôÝëåóç áðü $'
GOMSG1 fcs "** Áäýíáôç ç óõíÝ÷éóç ÷ùñßò ðñïçãïýìåíï SWI **"
SWIMSG fcs 'C: ÓõíÝ÷éóç',LF
#else
EXECMSG fcs 'Run from $'
GOMSG1 fcs "** Can't continue without a prior SWI **"
SWIMSG fcs 'C: Continue',LF
#endif
SWMSG1 fcc ' R E G I S T E R S',LF
fcs '-------------------',LF
SWMSG2 fcs ' A='
SWMSG3 fcs ' B='
SWMSG4 fcs ' X='
SWMSG5 fcs ' Y='
SWMSG6 fcs ' S='
SWMSG7 fcs ' PC='
SWMSG8 fcs ' S X H I N Z V C'
SWMSG9 fcs ' '
SWMSG10 fcs ' STACK = '
#ifdef GREEK
EXMSG1 fcc '* ÅÎÅÔÁÓÇ ÌÍÇÌÇÓ *',LF,LF
fcc '+ Þ - êßíçóç <- êáé -> óôçí ìíÞìç',LF
fcc '/ ãéá ôñïðïðïßçóç ðåñéå÷ïìÝíùí',LF
fcc '<ENTER> ãéá Ýîïäï',LF
fcs 'ÄÉÅÕÈÕÍÓÇ?'
#else
EXMSG1 fcc '* EXAMINE MEMORY *',LF,LF
fcc '+ or - move <- and -> in memory',LF
fcc '/ to modify contents',LF
fcc '<ENTER> to exit',LF
fcs 'ADDRESS?'
#endif
#ifdef GREEK
PSCALEM fcc 'Äéáßñåóç ìå: ÐëÞêôñï',LF
#else