-
Notifications
You must be signed in to change notification settings - Fork 1
/
CMakeLists.txt
65 lines (56 loc) · 2.12 KB
/
CMakeLists.txt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
cmake_minimum_required(VERSION 3.21)
project(
gpu_ptr
VERSION 0.0.1
LANGUAGES CXX)
# check if the project is top-level
if(CMAKE_PROJECT_NAME STREQUAL PROJECT_NAME)
set(GPU_PTR_IS_TOPLEVEL_PROJECT ON)
else()
set(GPU_PTR_IS_TOPLEVEL_PROJECT OFF)
endif()
# options
option(ENABLE_HIP "Enable HIP support" OFF)
option(GPU_PTR_BUILD_TEST "Build ${PROJECT_NAME} tests"
${GPU_PTR_IS_TOPLEVEL_PROJECT})
# library
include(GNUInstallDirs)
add_library(${PROJECT_NAME} INTERFACE)
add_library(${PROJECT_NAME}::${PROJECT_NAME} ALIAS ${PROJECT_NAME})
target_compile_features(${PROJECT_NAME} INTERFACE cxx_std_20)
target_compile_definitions(${PROJECT_NAME}
INTERFACE $<$<BOOL:${ENABLE_HIP}>:ENABLE_HIP>)
target_include_directories(
${PROJECT_NAME}
INTERFACE $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>)
set_target_properties(${PROJECT_NAME} PROPERTIES VERSION ${PROJECT_VERSION})
# install
if(GPU_PTR_IS_TOPLEVEL_PROJECT)
install(TARGETS ${PROJECT_NAME} EXPORT ${PROJECT_NAME}_Targets)
install(
EXPORT ${PROJECT_NAME}_Targets
FILE ${PROJECT_NAME}Targets.cmake
NAMESPACE ${PROJECT_NAME}::
DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME})
include(CMakePackageConfigHelpers)
write_basic_package_version_file(
${PROJECT_NAME}ConfigVersion.cmake COMPATIBILITY SameMajorVersion
ARCH_INDEPENDENT)
configure_package_config_file(
"${PROJECT_SOURCE_DIR}/cmake/${PROJECT_NAME}Config.cmake.in"
"${PROJECT_BINARY_DIR}/${PROJECT_NAME}Config.cmake"
INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME})
# install config files
install(FILES "${PROJECT_BINARY_DIR}/${PROJECT_NAME}Config.cmake"
"${PROJECT_BINARY_DIR}/${PROJECT_NAME}ConfigVersion.cmake"
DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME})
# install header files
install(DIRECTORY ${PROJECT_SOURCE_DIR}/include/
DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
endif()
# test
if(GPU_PTR_BUILD_TEST)
enable_testing()
add_subdirectory(test)
endif()