forked from neo-ai/neo-ai-dlr
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Jenkinsfile
168 lines (157 loc) · 4.49 KB
/
Jenkinsfile
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
#!/usr/bin/groovy
// -*- mode: groovy -*-
// Jenkins pipeline
// See documents at https://jenkins.io/doc/book/pipeline/jenkinsfile/
// List of cloud targets
def cloudTargetMatrix = [
"c4", "c5", "m4", "m5"
]
def inferenceContainerApps = [
"xgboost", "image_classification"
]
/* Pipeline definition */
pipeline {
// Each stage specify its own agent
agent none
// Set up common job properties
options {
ansiColor('xterm') // Use color in terminal
timestamps() // Show timestamp
timeout(time: 120, unit: 'MINUTES') // Timeout after 2 hours
buildDiscarder(logRotator(numToKeepStr: '10')) // Rotate build logs
}
// Build stages
stages {
stage('Jenkins: Get sources') {
agent {
label 'cpu-build'
}
steps {
checkoutSrcs()
stash name: 'srcs', excludes: '.git/'
milestone label: 'Sources ready', ordinal: 1
}
}
stage('Jenkins: Build') {
steps {
script {
parallel ([ "build-amd64-cpu" : { AMD64BuildCPU() },
"build-amd64-gpu" : { AMD64BuildGPU() } ])
}
}
}
stage('Jenkins: Install & Test') {
steps {
script {
parallel (cloudTargetMatrix.collectEntries{
[(it): { CloudInstallAndTest(it) } ]
})
}
}
}
stage('Jenkins: Build Container') {
agent {
label 'cpu-build'
}
steps {
script {
parallel (inferenceContainerApps.collectEntries{
[(it): { BuildInferenceContainer(it) } ]
})
}
}
}
}
}
/* Function definitions to follow */
// Check out source code
def checkoutSrcs() {
retry(5) {
try {
timeout(time: 2, unit: 'MINUTES') {
checkout scm
sh 'git submodule update --init --recursive'
}
} catch (exc) {
deleteDir()
error "Failed to fetch source codes"
}
}
}
// Build for AMD64 CPU target
def AMD64BuildCPU() {
def nodeReq = "ubuntu && amd64 && cpu-build"
def dockerTarget = "cpu_bare"
def dockerArgs = ""
node(nodeReq) {
unstash name: 'srcs'
echo "Building universal artifact for AMD64, CPU-only"
sh """
tests/ci_build/ci_build.sh ${dockerTarget} ${dockerArgs} tests/ci_build/build_via_cmake.sh
tests/ci_build/ci_build.sh ${dockerTarget} ${dockerArgs} tests/ci_build/create_wheel.sh manylinux1_x86_64
"""
stash name: 'dlr_cpu_whl', includes: 'python/dist/*.whl'
}
}
// Build for AMD64 + CUDA target
def AMD64BuildGPU() {
def nodeReq = "ubuntu && amd64 && gpu-build"
node(nodeReq) {
unstash name: 'srcs'
echo "Building artifact for AMD64 with GPU capability. Using CUDA 8.0, CuDNN 7, TensorRT 4"
sh """
tests/ci_build/build_via_cmake.sh -DUSE_CUDA=ON -DUSE_CUDNN=ON -DUSE_TENSORRT=/usr/src/tensorrt
PYTHON_COMMAND=/opt/python/bin/python tests/ci_build/create_wheel.sh ubuntu1404_cuda80_cudnn7_tensorrt4_amd64
"""
stash name: 'dlr_gpu_whl', includes: 'python/dist/*.whl'
}
}
// Install and test DLR for cloud targets
def CloudInstallAndTest(cloudTarget) {
def nodeReq = "ubuntu && amd64 && ${cloudTarget}"
node(nodeReq) {
echo "Installing DLR package for ${cloudTarget} target"
if (cloudTarget == "p2" || cloudTarget == "p3") {
unstash 'dlr_gpu_whl'
} else {
unstash 'dlr_cpu_whl'
}
sh """
ls -lh python/dist/*.whl
pip3 install python/dist/*.whl
"""
if (cloudTarget == "p2" || cloudTarget == "p3") {
sh """
sudo pip3 install --upgrade --force-reinstall tensorflow_gpu
"""
} else {
sh """
sudo pip3 install --upgrade --force-reinstall tensorflow
"""
}
sh """
type toco_from_protos
"""
echo "Running integration tests..."
unstash name: 'srcs'
sh """
python3 tests/python/integration/load_and_run_tvm_model.py
python3 tests/python/integration/load_and_run_treelite_model.py
python3 -m pytest -v --fulltrace -s tests/python/unittest/test_get_set_input.py
python3 -m pytest -v --fulltrace -s tests/python/unittest/test_tf_model.py
python3 -m pytest -v --fulltrace -s tests/python/unittest/test_tflite_model.py
"""
}
}
// Build DLR inference containers
def BuildInferenceContainer(app) {
def nodeReq = "ubuntu && amd64 && cpu-build"
node(nodeReq) {
unstash name: 'srcs'
echo "Building inference container ${app}"
sh """
cd container
docker build --build-arg APP=${app} -t ${app}-cpu -f Dockerfile.cpu .
"""
}
}